Many many thanks, after so long without much movement in open source photography...

Many many thanks, after so long without much movement in open source photography tools things are truly becoming exciting! In case someone wants to build the it using Nix I have pasted a quick and dirty port below. Not sure if I am willing to act as maintainer in Nixpkgs given my lack of experience with Qt and the tool itself, but hopefully it can prove as a starting point for someone that is or perhaps even if someone wants to build it on macOS (it does not look that difficult to adapt it for Mac):

  # vim: set ts=8 sw=2 sts=2 et:
  
  # Needs post-20.09 nixpkgs for `lensfun`, I have nixpkgs checked out and import it when building:
  #
  #   nix-build --no-out-link -I nixpkgs=$HOME/repo/nixpkgs -E 'with import <nixpkgs> {}; libsForQt5.callPackage ./default.nix {}'
  
  { pkgs ? import <nixpkgs> { }, cmake, curl, exiv2, libarchive, libjpeg, libraw
  , libtiff, mkDerivation, pkg-config, qtbase, qtquickcontrols2 }:
  let
    librtprocess =
      pkgs.librtprocess.overrideAttrs (oldAttrs: rec { version = "0.10.0"; });
    # “[Use the] latest git version for Linux and MacOS.”
    lensfun = pkgs.lensfun.overrideAttrs (oldAttrs: rec {
      version = "202012142";
      src = pkgs.fetchFromGitHub {
        owner = "lensfun";
        repo = "lensfun";
        rev = "4672d765a17bfef7bc994ca7008cb717c61045d5";
        sha256 = "00x35xhpn55j7f8qzakb6wl1ccbljg1gqjb93jl9w3mha2bzsr41";
      };
    });
  in mkDerivation rec {
    version = "0.11.0";
    pname = "filmulator-gui";
    src = pkgs.fetchFromGitHub {
      owner = "CarVac";
      repo = "${pname}";
      rev = "v${version}";
      sha256 = "0gdw4mxawh8lh4yvq521h3skjc46fpb0wvycy4sl2cm560d26sy6";
    };
    sourceRoot = "source/filmulator-gui";
  
    nativeBuildInputs = [ cmake pkg-config ];
  
    cmakeFlags = [ "-DCMAKE_BUILD_TYPE=RELEASE" ];
  
    buildInputs = [
      curl
      exiv2
      lensfun
      libarchive
      libjpeg
      libraw
      librtprocess
      libtiff
      qtbase
      qtquickcontrols2
    ];
  
    meta.broken = builtins.compareVersions qtbase.version "5.15" < 0;
  }